Wie man mit einer Videokamera die Bildfrequenz an einer Filmkamera kontrollieren kann/ an der Beaulieu 4008 /R16 perfekt einstellen kann

[jacquestati]

Meine XT2 kann im Videomodus diverse Geschwindigkeiten, 23,98, 24 und 25 fps, in 2K sogar Zeitlupe. Die Bildraten sind bei Videokameras immer quarzgeregelt, das kann man sich besonders gut an der Beaulieu 4008 /R16 mit stufenlos einstellbarer Geschwindgkeit zu Nutze machen. Die Kameras werden gegenüber jeweils auf einem Stativ aufgestellt, die Videokamera geht in den Makromodus, und mit der Videokamera wird der Schwingspiegel an der Beaulieu scharf eingestellt. 25 fps sind natürlich äußerst praktisch, wenn man später digitalisieren will, so habe ich die XT2 ensprechend eingestellt. Läßt man die Filmkamera dann laufen und betrachtet den Schwingspiegel im Sucher der Videokamera, wird sich das Bild mit der Interferenzfrequenz bewegen, falls die Filmkamera zu langsam oder zu schnell läuft. Mit der stufenlosen Geschwindigkeitseinstellung an der Beaulieu kann man die Bildrate exakt auf 25 fps einjustieren, oder auch auf 24 fps, wenn die Videokamera diese Bildfrequenz hergibt. Mit dem Festestllrädchen an der Beaulieu R16 ist es dann ein für allemal eingestellt. Ich hatte das Glück, über Gizmo das Gebuhr Quarzmodul für die R16 zu bekommen, Herr Rehberger hat es eingebaut. Im Quarzmodus 25 fps steht die Bildrate bombenfest. Aber auch ungequarzt läuft die 4008/ R16 außerordentlich stabil.

Andere Fimkameras kann man damit sicher auch überprüfen, ich denke, dass die Schrauber hier  die Potis kennen, mit denen man z.B. an der Nizo die Bildfrequnz einstellen kann. Da hilft bei geöffnetem Kassettenfach dann ggfls. eine Lampe von hinten.

 

 

[Friedemann Wachsmuth]

Sehr schöne Anleitung!

 

Man braucht dazu gar nicht unbedingt eine Videokamera, ein einfaches Stroboskop tut es auch.
 

Ein Arduino, ein Transistor und eine helle LED reichen schon, dann regelt man einfach bis der Greifer im Lauf "steht". Leider haben viele S8 Kameras mechanische Geschwindigkeitsbegrenzungen, die sich oft kaum oder auch nur unzureichend regeln lassen. Oder man kommt an die Regelung kaum ran, da die zB direkt hinten am Motor hängt...

[Friedemann Wachsmuth]

Hier mal der Code für so ein Stroboskop mit hoher Genauigkeit.

Das ganze ist nicht sonderlich aufgeräumt oder komfortabel, aber kann gut als Basis für mehr dienen. Natürlich sollte der Arduino (mit 328P oder 168P) eine Version mit Quarz sein, die an China-Versionen gelegentlich verwendeten Keramikresonatoren sind weniger genau.

 

Der Code unterstützt (bisher) 6 Geschwindigkeiten, in der Setup Routine wählt man einfach die gewünschte aus. An Pin 7 wird dann eine LED zum Blitzen gebracht. Nimmt man eine extra helle, weiße LED mit mehr als 10 mA Stromaufnahme, sollte man sie noch über einen Transistor schalten.

 

 

#define FPS_18      1
#define FPS_24      2
#define FPS_25      3
#define FPS_9       4
#define FPS_16_2_3  5

#define strobeLed   7 

// Timer Variables
int timerFactor = 0;    // this is used for the Timer1 postscaler, since multiples of 18 and 24 Hz give better accuracy
volatile int timerDivider = 0;  // For Modulo in the ISR
volatile unsigned long timerFrames = 0;

unsigned long ledOnMillis = 0;
bool pulseNow = false;

void setup()
{
    Serial.begin(115200);
    pinMode(strobeLed, OUTPUT);
    setupTimer1forFps(FPS_24);
}

void loop()
{
    if (pulseNow) {
        digitalWrite(strobeLed, HIGH);
        pulseNow = false;
        ledOnMillis = millis();
    } else if ((millis() - ledOnMillis) > 3) {
        digitalWrite(strobeLed, LOW);
    }
}

ISR(TIMER1_COMPA_vect)
{
    if (timerDivider == 0)
    {
        pulseNow = true;
    }
    timerDivider++;
    timerDivider %= timerFactor;
}

bool setupTimer1forFps(byte sollFpsState)
{
    // start with a new sync point, no need to catch up differences from before.
    timerFrames = 0;
    timerDivider = 0;

    if (sollFpsState >= 1 && sollFpsState <= 5)
    {
        Serial.print(F("New Timer FPS State: "));
        Serial.println(sollFpsState);

        noInterrupts();
        // Clear registers
        TCCR1A = 0;
        TCCR1B = 0;
        TCNT1 = 0;
        // CTC
        TCCR1B |= (1 << WGM12);

        switch (sollFpsState)
        {
        case FPS_9:
            OCR1A = 10100; // 198.000198000198 Hz (16000000/((10100+1)*8)),
            //              divided by 22 is 9,000009.. Hz
            //
            TCCR1B |= (1 << CS11); // Prescaler 8
            timerFactor = 22;

            break;
        case FPS_16_2_3:
            OCR1A = 14999;                       // 16 2/3 Hz (16000000/((14999+1)*64))
            TCCR1B |= (1 << CS11) | (1 << CS10); // Prescaler 64
            timerFactor = 1;

            break;
        case FPS_18:
            OCR1A = 10100; // 198.000198000198 Hz (16000000/((10100+1)*8)),
            //              divided by 11 is 18.000018.. Hz
            //              or 18 2/111,111
            //              or 2,000,000/111,111
            //
            TCCR1B |= (1 << CS11); // Prescaler 8
            timerFactor = 11;

            break;
        case FPS_24:
            OCR1A = 60605; // 264.000264000264 Hz (16000000/((60605+1)*1)),
            //               divided by 11 is 24.000024.. Hz
            //               or 24 8/333,333
            //               or 8,000,000 / 333,333
            //
            TCCR1B |= (1 << CS10); // Prescaler 1
            timerFactor = 11;

            break;
        case FPS_25:
            OCR1A = 624;                         // 25 Hz (16000000/((624+1)*1024))
            TCCR1B |= (1 << CS12) | (1 << CS10); // Prescaler 1024
            timerFactor = 1;

            break;

        default:
            break;
        }
        // Output Compare Match A Interrupt Enable
        TIMSK1 |= (1 << OCIE1A);
        interrupts();
    }
    else
    {
        // invalid fps requested
        Serial.println(F("Invalid FPS request"));
        return false;
    }
}

 

[jacquestati]

Merci Friedemann, aber bis ich das drauf habe,  hat'ne alte Frau eine ganze Insel bevölkert. Werde mich aber als zukünftiger Altersteilzeitler damit beschäftigen.

[uhuplus]

Man nehme, was man hat. Die beste Filmkamera ist die, die man dabei hat, habe ich mal gehört...

[jacquestati]

Genau so ist es!

[Helge]

Man kann auch sehr schön einen eventuellen Zweibandvertonungs-Ausgang nutzen. Das Signal über den PC aufzeichnen (Audioprogramm) und ausmessen (ersatzweise das Signal eines Blitzkontaktes).

Ist nicht ganz so komfortabel wie die beiden anderen beschriebenen Methoden, aber geht gut.

Hat bei mir zu der Erkenntnis von 17,4 B/s bei eingestellten 18 B/s geführt, leider bisher noch keine Möglichkeit gefunden, das bei der Professional zu korrigieren…☹️

Bearbeitet 12. Februar 2023 von Helge (Änderungen anzeigen)

[jacquestati]

Prinzipiell kann man das auch bei Filmprojektoren machen, die Bauer Studioklasse, z.B. der 610er oder der Bauer P8, die eine Motorregelung  mit dem TCA 955 haben, kann man (f)einregulieren. Nur sollte man nicht direkt mit der Projektionslampe auf den Kamerasensor leuchten...🥵

Bearbeitet 12. Februar 2023 von jacquestati (Änderungen anzeigen)

[Friedemann Wachsmuth]

vor 1 Stunde schrieb jacquestati:

Nur sollte man nicht direkt mit der Projektionslampe auf den Kamerasensor leuchten

Im Einfädelmodus geht das 🙂

Wobei... quatsch. In dem geht die Lampe ja ganz aus. Also diesen Kommentar gern löschen...

Bearbeitet 12. Februar 2023 von F. Wachsmuth (Änderungen anzeigen)

[Henry08]

vor 3 Stunden schrieb jacquestati:

Prinzipiell kann man das auch bei Filmprojektoren machen, die Bauer Studioklasse, z.B. der 610er oder der Bauer P8, die eine Motorregelung  mit dem TCA 955 haben, kann man (f)einregulieren.

Wenn man diesen Drehzahlmesser von Jamara vor das Objektiv bei eingeschalteter Lampe hält, dann kann man mit einem Poti am Gehäuse des Projektors ( mit dem Poti auf der Motorplatine verbunden ) schön die Geschwindigkeit einstellen. 100 bedeutet 16,6 B/sec, 108 18 B/sec. Van Eck hat das Nachfolgemodell.

rpm check von Jamara: